Vlookup не может найти ссылку на ячейку - PullRequest
Новая
       19

Vlookup не может найти ссылку на ячейку

0 голосов
/ 14 февраля 2019

Я использую Google Sheets для поиска формулы, но код возвращается, говоря:

"невозможно сопоставить с '25oz'"

Ссылка длялист здесь:
https://docs.google.com/spreadsheets/d/1K1Hb9xV8Ky51Vdiv0SG-zKOEH0ELPNBYwMWhDFfm4l0/edit#gid=168328825

Конкретная часть, с которой у меня возникает ошибка, - «Мастер-коктейль» D5, где он пытается найти либо мой листок «Алкоголь», либо лист «Пиво Н.А. Бев».за соответствующую цену, основанную на используемой унции.

Код, который я использую в ячейке: 

=ArrayFormula(IF(C5="","",vlookup($B5,{'Beer NA Bev'!$A$63:$H$71;Spirits!$A$2:$I$325},MATCH($C5,{'Beer NA Bev'!$A$62:$K$62;Spirits!$A$3:$J$3},0),FALSE)))

1 Ответ

0 голосов
/ 14 февраля 2019

  • прежде всего {'Beer NA Bev'!$A$63:$H$71; Spirits!$A$2:$I$325}
    должно быть: {'Beer NA Bev'!$A$63:$I$71; Spirits!$A$2:$I$325} например.то же количество столбцов

  • тогда вы можете отбросить целое MATCH и поместить туда IFERROR, под которым будет IF с двумя VLOOKUP (один для TRUEside и one для FALSE side), чтобы различать пиво и спиртные напитки, потому что у вас есть .25oz на обоих листах.и затем вы можете вставить простой IFS, чтобы проверить / найти нужную цену .25oz и номер столбца возврата для основного VLOOKUP.
    проверить эту похожую проблему: https://stackoverflow.com/a/54680420/5632629

как-то так: 

 IFERROR(IF(VLOOKUP(B5, 'Beer NA Bev'!$A$63:$I$71, 1, 0)<>"", IFS(C5=".25oz", 5, 
                                                                  C5=".5oz",  6, 
                                                                  C5=".75oz", 7, 
                                                                  C5="1oz",   8,
                                                                  C5="2oz",   9), ), 
         IF(VLOOKUP(B5, Spirits!$A$2:$I$325,       1, 0)<>"", IFS(C5="2oz",   4,
                                                                  C5="1.5oz", 5,
                                                                  C5="1oz",   6,
                                                                  C5=".75oz", 7,
                                                                  C5=".5oz",  8,
                                                                  C5=".25oz", 9), ))

и вся формула будет выглядеть так: 

=ARRAYFORMULA(IF(C5="", "",
 VLOOKUP($B5, {'Beer NA Bev'!$A$63:$I$71;
                     Spirits!$A$2:$I$325},
 IFERROR(IF(VLOOKUP(B5, 'Beer NA Bev'!$A$63:$I$71, 1, 0)<>"", IFS(C5=".25oz", 5, 
                                                                  C5=".5oz",  6, 
                                                                  C5=".75oz", 7, 
                                                                  C5="1oz",   8,
                                                                  C5="2oz",   9), ), 
         IF(VLOOKUP(B5, Spirits!$A$2:$I$325,       1, 0)<>"", IFS(C5="2oz",   4,
                                                                  C5="1.5oz", 5,
                                                                  C5="1oz",   6,
                                                                  C5=".75oz", 7,
                                                                  C5=".5oz",  8,
                                                                  C5=".25oz", 9), )), 0)))

...