Объединение двух шейдеров в один шейдер - PullRequest
Новая
       47

Объединение двух шейдеров в один шейдер

0 голосов
/ 13 декабря 2018

Unity Project, хотите объединить эти два шейдера в один шейдер, чтобы получить их функциональность.Один шейдер предназначен для освещения, другой шейдер для лучшего рендеринга.Как мне объединить? 

Shader "Transparent/Cutout/Lit3dSprite" {
Properties{
    _MainCol("Main Tint", Color) = (1,1,1,1)
    _MainTex("Main Texture", 2D) = "white" {}
    _Cutoff("Alpha cutoff", Range(0,1)) = 0.5
}

SubShader{
    Tags {"Queue" = "AlphaTest" "IgnoreProjector" = "True" "RenderType" = "TransparentCutout" "PreviewType" = "Plane"}
    Cull Off
    LOD 200

    CGPROGRAM
    #pragma surface surf SimpleLambert alphatest:_Cutoff addshadow fullforwardshadows
    #pragma target 3.0

    sampler2D _MainTex;
    fixed4 _MainCol;

    half4 LightingSimpleLambert(SurfaceOutput s, half3 lightDir, half atten) 

{
            half4 c;
            c.rgb = s.Albedo * _MainCol.rgb * (atten)* _LightColor0.rgb;
            c.a = s.Alpha;
            return c;
        }

        struct Input {
            float2 uv_MainTex;
        };

        void surf(Input IN, inout SurfaceOutput o) {
            fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _MainCol;
            o.Albedo = lerp(c.rgb, c.rgb, c.a);
            o.Alpha = c.a;
        }
        ENDCG
    }

    Fallback "Transparent/Cutout/VertexLit"
}

Шейдер 2: 

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "RetroAA/Sprite"
{
    Properties
    {
        [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
        _Color ("Tint", Color) = (1,0,0,0)
    }
    SubShader
    {
        Tags {
            "Queue"="Transparent" 
            "IgnoreProjector"="True" 
            "RenderType"="Transparent" 
            "PreviewType"="Plane"
            "CanUseSpriteAtlas"="True"
        }
        LOD 100

        Cull Off
        Lighting Off
        ZWrite Off
        Blend SrcAlpha OneMinusSrcAlpha

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fog

            #include "RetroAA.cginc"

            struct appdata {
                float4 vertex : POSITION;
                float4 color : COLOR;
                float2 uv : TEXCOORD0;
            };

            struct v2f {
                float4 vertex : SV_POSITION;
                fixed4 color : COLOR;
                float2 uv : TEXCOORD0;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float4 _MainTex_TexelSize;

            float4 _Color;

            v2f vert(appdata v){
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.color = v.color * _Color;

                return o;
            }

            fixed4 frag(v2f i) : SV_Target {
                fixed4 color = RetroAA(_MainTex, i.uv, _MainTex_TexelSize);
                return i.color*color*color.a;
            }
            ENDCG
        }
    }
}

1 Ответ

0 голосов
/ 13 декабря 2018

Второй шейдер не слишком сложен, и его можно объединить с первым, просто используя код второго шейдера, чтобы изменить способ вычисления surf первого шейдера fixed4 c.

Вам также нужно будет включить "RetroAA.cginc" и включить размер текстур основной текстуры в переменные шейдера.

Однако первый шейдер предполагает, что нет частичной прозрачности, ивторой шейдер требует этого, так что вы должны учесть это.Вам нужно будет использовать альфа-смешение, изменить RenderType и Queue на Transparent и указать ZWrite Off.

Вот то, что все это может выглядеть вместе: 

Shader "Transparent/Cutout/Lit3dSprite" {
Properties{
    _MainCol("Main Tint", Color) = (1,1,1,1)
    _MainTex("Main Texture", 2D) = "white" {}
    _Cutoff("Alpha cutoff", Range(0,1)) = 0.5
}

SubShader{
    // change RenderType and Queue to Transparent
    Tags {"Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" "PreviewType" = "Plane"}
    Cull Off
    ZWrite Off // Add this
    LOD 200

    // Enable Alpha blending here
    Blend SrcAlpha OneMinusSrcAlpha 

    CGPROGRAM
    // Enable Alpha blending here also
    #pragma surface surf SimpleLambert alphatest:_Cutoff addshadow fullforwardshadows alpha:blend
    #pragma target 3.0

    #include "RetroAA.cginc" // Add this

    sampler2D _MainTex;
    float4 _MainTex_TexelSize; // Add this
    fixed4 _MainCol;

    half4 LightingSimpleLambert(SurfaceOutput s, half3 lightDir, half atten) 

{
            half4 c;
            c.rgb = s.Albedo * _MainCol.rgb * (atten)* _LightColor0.rgb;
            c.a = s.Alpha;
            return c;
        }

        struct Input {
            float2 uv_MainTex;
        };

        void surf(Input IN, inout SurfaceOutput o) {
            // replace this line: 
            // fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _MainCol;

            // with this
            fixed4 c = RetroAA(_MainTex, IN.uv_MainTex, _MainTex_TexelSize);                 o.Albedo = lerp(c.rgb, c.rgb, c.a) * _MainCol;

            o.Albedo = lerp(c.rgb, c.rgb, c.a);
            o.Alpha = c.a;
        }
        ENDCG
    }

    Fallback "Transparent/Cutout/VertexLit"
}

Вам может понадобиться уменьшить Alpha cutoff до нуля или другого низкого значения, чтобы АА работала хорошо.

...