Шейдер Unity 3d Sprite (Как ограничить максимальную яркость до 1 при включении нескольких источников света)

Question

Я создаю видеоигру в Unity.Каждый спрайт визуализируется с помощью рендерера спрайтов с материалом, который имеет CornucopiaShader.shader.У меня проблема в том, что я хочу ограничить максимальную яркость (или цвет) спрайта, чтобы он был просто нормальным изображением спрайта, независимо от того, сколько точечных источников света поражает его, интенсивности источников света, а также рассеянный свет на сцене единства.Когда интенсивность света, падающего на спрайт, ниже этого максимального уровня яркости, я хочу, чтобы он действовал как обычный освещенный спрайт и был черным, если на него не падали огни, и был наполовину освещен, если интенсивность 0,5 поражала его и т. Д.,и все между ними, как обычно. Задача 1: В итоге, если три источника света, скажем, 5, попадают в спрайт, я хочу, чтобы спрайт просто выглядел как обычная яркость 1, а не светился белым светом.

Поскольку проигрывательможет вращаться, как бумага Марио, и переключать стороны, действующий код шейдера действует таким же образом, а также в настоящее время свет, который попадает с задней стороны, также должен освещать обе стороны, как это происходит в настоящее время в шейдере. Проблема 2: Но другая проблема, с которой я столкнулся, как это видно на четырех изображениях, которые я включил, это когда я переворачиваю плеер, интенсивность меняется.

Я пытался выяснить,Эти две проблемы в течение 3 дней подряд и не могут понять это.

Изображение 1

Изображение 2

Изображение 3

Изображение 4

Shader "Custom/CornucopiaShader" {

Properties{
    _MainCol("Main Tint", Color) = (1,1,1,1)
    _MainTex("Main Texture", 2D) = "white" {}
    _Cutoff("Alpha cutoff", Range(0,0.5)) = 0.5
}

SubShader{
    Tags {"Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" "PreviewType" = "Plane"}
    Cull Off
    ZWrite Off
    LOD 200
    ColorMask RGB

    Blend SrcAlpha OneMinusSrcAlpha

    CGPROGRAM
    #pragma surface surf SimpleLambert alphatest:_Cutoff addshadow fullforwardshadows alpha:blend
    #pragma target 3.0

    #include "RetroAA.cginc"

    sampler2D _MainTex;
    float4 _MainTex_TexelSize;
    fixed4 _MainCol;

    half4 LightingSimpleLambert(SurfaceOutput s, half3 lightDir, half atten)
    {
        half4 c;

        c.rgb = s.Albedo * _MainCol.rgb * (atten)* _LightColor0.rgb;
        c.a = s.Alpha;

        return c;
    }

    struct Input {
        float2 uv_MainTex;
    };

    void surf(Input IN, inout SurfaceOutput o) {

        fixed4 c = RetroAA(_MainTex, IN.uv_MainTex, _MainTex_TexelSize);
        o.Albedo = lerp(c.rgb, c.rgb, c.a);
        o.Alpha = c.a;

    }
    ENDCG
}

Fallback "Transparent/Cutout/VertexLit"

}

#include "UnityCG.cginc"

#pragma target 3.0

fixed4 RetroAA(sampler2D tex, float2 uv, float4 texelSize){
    float2 texelCoord = uv*texelSize.zw;
    float2 hfw = 0.5*fwidth(texelCoord);
    float2 fl = floor(texelCoord - 0.5) + 0.5;
    float2 uvaa = (fl + smoothstep(0.5 - hfw, 0.5 + hfw, texelCoord -     fl))*texelSize.xy;

return tex2D(tex, uvaa);
}

Answer 1

Вы не можете сделать это с поверхностными шейдерами, но вы можете сделать это очень эффективно с вершинными фрагментными шейдерами.Unity хранит 4 источника света ближайших точек в наборе векторов, которые будут использоваться для источников света на каждую вершину (не важно).К счастью, они также доступны в фрагментном шейдере, так что вы можете использовать их, чтобы закрасить все 4 источника света за один проход!Когда вы суммируете все источники света, убедитесь, что их интенсивность не может превышать 1. Вот быстрый шейдер, который я собрал для вас:

Shader "Unlit/ToonTest"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Name "FORWARD"
        Tags { "LightMode" = "ForwardBase" "RenderType" = "TransparentCutout" "Queue"="AlphaTest"}
        Cull Off
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fog
            #pragma multi_compile_fwdbase

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                half3 normal : NORMAL;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
                float3 worldPos : TEXCOORD1;
                float3 ambient : TEXCOORD2;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.ambient = ShadeSH9(mul(unity_ObjectToWorld, float4(v.normal, 0.0 ))); // Ambient from spherical harmonics
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }

            float3 Shade4Lights (    
                float4 lightPosX, float4 lightPosY, float4 lightPosZ,
                float3 lightColor0, float3 lightColor1, float3 lightColor2, float3 lightColor3,
                float4 lightAttenSq,
                float3 pos)
            {
                // to light vectors
                float4 toLightX = lightPosX - pos.x;
                float4 toLightY = lightPosY - pos.y;
                float4 toLightZ = lightPosZ - pos.z;
                // squared lengths
                float4 lengthSq = 0;
                lengthSq += toLightX * toLightX;
                lengthSq += toLightY * toLightY;
                lengthSq += toLightZ * toLightZ;
                // don't produce NaNs if some vertex position overlaps with the light
                lengthSq = max(lengthSq, 0.000001);

                // attenuation
                float4 atten = 1.0 / (1.0 + lengthSq * lightAttenSq);
                float4 diff = atten; //ndotl * atten;
                // final color
                float3 col = 0;
                col += lightColor0 * diff.x;
                col += lightColor1 * diff.y;
                col += lightColor2 * diff.z;
                col += lightColor3 * diff.w;
                return col;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                half3 intensity = Shade4Lights(unity_4LightPosX0, unity_4LightPosY0, unity_4LightPosZ0, unity_LightColor[0], unity_LightColor[1], unity_LightColor[2], unity_LightColor[3], unity_4LightAtten0, i.worldPos);
                intensity = min((half3)1, i.ambient + intensity);

                col.rgb *= intensity;

                clip(col.a - 0.5);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);
                return col;
            }
            ENDCG
        }
    }
}

Функция "Shade4Lights" является модифицированной версиейUnity "Shade4PointLights", с рассеянным рассеянным освещением Ламберта (только ослабление).Вам также необходимо добавить функцию RetroAA в выборку текстур.Ваше значение отсечения - это «- 0.5» внутри функции «clip» - вы можете выставить это, если вам это нужно.Если вам нужно отбрасывать тени для этого шейдера, вы можете скопировать / вставить теневой проход из стандартного шейдера Unity (вы можете скачать исходный код с их страницы).Для получения тени вам необходимо добавить несколько строк в шейдер - снова проверьте исходный код для этого.

Подробнее о встроенных переменных шейдера можно прочитать здесь:

https://docs.unity3d.com/Manual/SL-UnityShaderVariables.html