Создание sha1-хэша строки в Oracle - PullRequest
Новая
       21

Создание sha1-хэша строки в Oracle

15 голосов
/ 17 ноября 2009

У меня проблема с созданием sha1-хэша строки в выборке в базе данных Oracle. Я сделал это в MSSQL следующим образом: 

SELECT *,HASHBYTES('SHA1',CAST(ID as varchar(10)+
  TextEntry1+TextEntry2+CAST(Timestamp as varchar(10)) as Hash
FROM dbo.ExampleTable
WHERE ID = [foo]

Однако я не могу найти похожую функцию для использования при работе с Oracle. Что касается моего приближения ко мне, я предполагаю, что dbms_crypto.hash_sh1 как-то связан с этим, но я пока не смог обернуть его вокруг ...

Любые указатели будут с благодарностью.

Ответы [ 4 ]

24 голосов
/ 17 ноября 2009

Пакет DBMS_CRYPTO является правильным пакетом для генерации хэшей. По умолчанию он не предоставляется PUBLIC, вам придется предоставить его специально (GRANT EXECUTE ON SYS.DBMS_CRYPTO TO user1).

Результат этой функции имеет тип данных RAW. Вы можете сохранить его в столбце RAW или преобразовать в VARCHAR2, используя функции RAWTOHEX или UTL_ENCODE.BASE64_ENCODE.

Функция HASH перегружена для приема трех типов данных в качестве входных данных: RAW, CLOB и BLOB. Из-за правил неявного преобразования , если вы используете VARCHAR2 в качестве ввода, Oracle попытается преобразовать его в RAW и, скорее всего, потерпит неудачу, так как это преобразование работает только с шестнадцатеричными строками.

Если вы используете VARCHAR2, вам необходимо преобразовать входные данные в двоичный тип данных или CLOB, например: 

DECLARE
   x RAW(20);
BEGIN
   SELECT sys.dbms_crypto.hash(utl_raw.cast_to_raw(col1||col2||to_char(col3)), 
                               sys.dbms_crypto.hash_sh1) 
     INTO x 
     FROM t;
END;

дополнительную информацию вы найдете в документации по DBMS_CRYPTO.hash

8 голосов
/ 28 февраля 2012

Пакет DBMS_crypto не поддерживает varchar2. Он работает с необработанным типом, поэтому, если вам нужен varchar2, вы должны конвертировать его. Вот пример функции, показывающей, как это сделать: 

declare
  p_string varchar2(2000) := 'Hello world !';
  lv_hash_value_md5    raw (100);
  lv_hash_value_sh1    raw (100);
  lv_varchar_key_md5   varchar2 (32);
  lv_varchar_key_sh1   varchar2 (40);
begin
  lv_hash_value_md5 :=
     dbms_crypto.hash (src   => utl_raw.cast_to_raw (p_string),
                       typ   => dbms_crypto.hash_md5);

  -- convert into varchar2
  select   lower (to_char (rawtohex (lv_hash_value_md5)))
    into   lv_varchar_key_md5
    from   dual;

  lv_hash_value_sh1 :=
     dbms_crypto.hash (src   => utl_raw.cast_to_raw (p_string),
                       typ   => dbms_crypto.hash_sh1);

  -- convert into varchar2
  select   lower (to_char (rawtohex (lv_hash_value_sh1)))
    into   lv_varchar_key_sh1
    from   dual;

  --
  dbms_output.put_line('String to encrypt : '||p_string);
  dbms_output.put_line('MD5 encryption : '||lv_varchar_key_md5);
  dbms_output.put_line('SHA1 encryption : '||lv_varchar_key_sh1);
end;
3 голосов
/ 18 сентября 2015

Вы можете определить эту функцию в вашем любимом пакете, который я определил в utils_pkg. 

FUNCTION SHA1(STRING_TO_ENCRIPT VARCHAR2) RETURN VARCHAR2 AS 
BEGIN 
RETURN LOWER(TO_CHAR(RAWTOHEX(SYS.DBMS_CRYPTO.HASH(UTL_RAW.CAST_TO_RAW(STRING_TO_ENCRIPT), SYS.DBMS_CRYPTO.HASH_SH1))));
END SHA1;

Теперь, чтобы назвать это 

SELECT UTILS_PKG.SHA1('My Text') AS SHA1 FROM DUAL;

Ответ 

SHA1
--------------------------------------------
5411d08baddc1ad09fa3329f9920814c33ea10c0

Вы можете выбрать столбец из некоторой таблицы: 

SELECT UTILS_PKG.SHA1(myTextColumn) FROM myTable;

Наслаждайтесь!

2 голосов
/ 08 июня 2018

Просто поставить его здесь, если кто-то будет искать.

В Oracle 12 вы можете использовать функцию standard_hash(<your_value>, <algorythm>). Если параметр <algorythm> не определен, он сгенерирует хэш SHA-1 (тип выходных данных raw(20))

...