Google Sheets SUMIF Text Formula - PullRequest
Новая
       23

Google Sheets SUMIF Text Formula

0 голосов
/ 27 апреля 2020

Хорошо, я скажу, что я не так хорош с Excel и еще хуже на Google листах. Я хотел бы знать, есть ли формула, которая проверяет имя кого-либо, а затем суммирует баллы, которые этот человек получил, к его общему количеству. Большое спасибо!

https://docs.google.com/spreadsheets/d/1D4M8Dlao8yFHJulNDff-i2jZJeVGGY_gejbAfzWdhFo/edit?usp=sharing - ссылка, если вы хотите ее проверить.

1 Ответ

1 голос
/ 27 апреля 2020

Полагаю, вы хотите, чтобы в столбце Punti tot. (R:R) была сумма всех TA Brawl (столбец C:C), Notte (L:L) и 50 Shades (H:H; в этом случае любой из двух игроков должен быть проверен, верно?) Для каждого игрока.

Вы можете использовать это в R2 (не забудьте удалить все ниже R2): 

={
  "Punti tot.";
  ARRAYFORMULA(
    IF(
      P3:P = ""; ;
          SUMIF(A3:A; P3:P; C3:C)
        + SUMIF(E3:E; P3:P; H3:H)
        + SUMIF(F3:F; P3:P; H3:H)
        + SUMIF(J3:J; P3:P; L3:L)
    )
  )
}

enter image description here

Обновление: вот еще одно решение, использующее QUERY, которое также сортирует игроков по общему количеству очков: 

=QUERY(
  {
    FILTER({A3:A\ C3:C}; A3:A <> "");
    FILTER({E3:E\ H3:H}; E3:E <> "");
    FILTER({F3:F\ H3:H}; F3:F <> "");
    FILTER({J3:J\ L3:L}; J3:J <> "")
  };
  "
    select Col1, SUM(Col2)
    group by Col1
    order by SUM(Col2) desc,
             Col1
    label Col1 'Player',
          SUM(Col2) 'Punti tot.'
  ";
  -1
)

enter image description here

И вы можете использовать это в O2 для рейтинга: 

={
  "Posizioni Finali";
  ARRAYFORMULA(
    RANK(
      FILTER(Q3:Q; Q3:Q <> "");
      FILTER(Q3:Q; Q3:Q <> "")
    )
  )
}

Таким образом, одинаковое количество очков дает игрокам одинаковое место. В противном случае hysen получит 9-е место, а Imurshh будет 10-м, потому что h идет раньше i .

enter image description here

...