Поддерживать лист акций в листах Google с отдельными листами инвентаризации и выдачи - PullRequest
Новая
       4

Поддерживать лист акций в листах Google с отдельными листами инвентаризации и выдачи

1 голос
/ 13 апреля 2020

У меня есть 2 листа с инвентарным и эмиссионным счетом, оба имеют номера образцов и их количество. Я хочу вести третий складской лист, который будет показывать номер образца, количество его запасов, количество выпусков и количество запасов. Подсчет запаса - это просто подсчет инвентаря - подсчет выпуска.

Таблицы подсчета и выпуска будут обновляться автоматически.

Номера образцов могут быть расположены по-разному в листах подсчета и подсчета выпуска. Более того, некоторые из выборок, которые могут присутствовать в подсчете, могут отсутствовать в подсчете выпусков, поэтому их счет в выпусках должен быть равен 0.

Я вставил ссылку на справочный лист, аналогичный мой вариант использования. Любая помощь будет оценена. Заранее спасибо!

https://docs.google.com/spreadsheets/d/1UDlCzA1WDkIWDNoEffihSH2rKegKHciSP1kqp_QJ-kY/edit?usp=sharing

1 Ответ

1 голос
/ 13 апреля 2020

Вы можете поместить формулы массива в заголовки, которые будут выполнять то, что вы просите.

Все уникальные номера образцов : 

={
  "Sample Number";
  SORT(UNIQUE(
    {
      UNIQUE(FILTER(Issuance!A2:A, Issuance!A2:A <> ""));
      UNIQUE(FILTER(Inventory!A2:A, Inventory!A2:A <> ""))
    }
  ))
}

enter image description here

инвентарный подсчет : 

={
  "Inventory Count";
  ARRAYFORMULA(IF(B2:B = "", "", COUNTIF(Inventory!A2:A, B2:B)))
}

enter image description here

счет выдачи : 

={
  "Issuance Count";
  ARRAYFORMULA(IF(B2:B = "", "", COUNTIF(Issuance!A2:A, B2:B)))
}

enter image description here

Запас : 

={
  "Stock";
  ARRAYFORMULA(IF(B2:B = "", "", C2:C - D2:D))
}

enter image description here

Посмотрите на образец, все это есть.

...