ActionScript2.0: дуга рисования для угла треугольника - PullRequest
Новая
       26

ActionScript2.0: дуга рисования для угла треугольника

0 голосов
/ 30 марта 2010

как нарисовать дугу в случайном угле созданного треугольника с помощью flash actionscript 2.0.

Спасибо всем. альтернативный текст http://www.freeimagehosting.net/uploads/8289d7feff.png

Я бы хотел нарисовать красную дугу под углом каждого треугольника. Примечание. Треугольник будет создан случайным образом.

1 Ответ

1 голос
/ 31 марта 2010

Один простой способ - нарисовать круг в каждом углу, а затем использовать копию вашего треугольника, чтобы замаскировать круги так, чтобы были видны только внутренние дуги.

Например, создайте мувиклип в вашей библиотеке с именем «circle», содержащий незаполненный красный кружок с центром в точке вставки клипа (обязательно отметьте «Export for Actionscript» в его свойствах).

Тогда вы можете нарисовать свой треугольник примерно так: 

import flash.geom.Point;

function randomPoint():Point {  //return a random point on the stage
    var p:Point = new Point(Math.floor(Math.random()*Stage.width), Math.floor(Math.random()*Stage.height));
    return p;
}

function drawTriangle(mc:MovieClip, q1:Point, q2:Point, q3:Point):Void {//draw a triangle through 3 points
    var stroke=2;//line weight of triangle
    mc.lineStyle(stroke, 0x000000, 100, true, "none", "round", "round");
    mc.moveTo(q1.x, q1.y);
    mc.lineTo(q2.x, q2.y);
    mc.lineTo(q3.x, q3.y);
    mc.lineTo(q1.x, q1.y);
}

function arcTriangle():MovieClip {  //main function to draw a triangle with corner arcs
    //make a new movieclip t which will hold our triangle parts
    var depth=this.getNextHighestDepth();
    var t:MovieClip = this.createEmptyMovieClip("t"+depth, depth);

    //define 3 random points (stored as properties of t)
    t.p1=randomPoint();
    t.p2=randomPoint();
    t.p3=randomPoint();

    //draw a triangle
    t.createEmptyMovieClip("triangle", 0);
    drawTriangle(t.triangle, t.p1, t.p2, t.p3);

    //draw a filled triangle to use as a mask
    t.createEmptyMovieClip("mask", 1);
    t.mask.beginFill(0xF0F0F0);
    drawTriangle(t.mask, t.p1, t.p2, t.p3);
    t.mask.endFill();
    t.mask._alpha=0;

    //add a red circle to each corner
    t.createEmptyMovieClip("arcHolder", 2);
    t.arcHolder.attachMovie("circle", "arc1",1,{_x:t.p1.x, _y:t.p1.y});
    t.arcHolder.attachMovie("circle", "arc2",2,{_x:t.p2.x, _y:t.p2.y});
    t.arcHolder.attachMovie("circle", "arc3",3,{_x:t.p3.x, _y:t.p3.y});

    //mask the circles so only the interior arcs are visible
    t.arcHolder.setMask(t.mask);

    return t;
}

var myTriangle:MovieClip = arcTriangle();

и вуаля http://roi.webfactional.com/img/so/triangle.jpg

...