Delphi DIB с заголовком DIB в TBitmap - PullRequest
Новая
       99

Delphi DIB с заголовком DIB в TBitmap

0 голосов
/ 29 января 2010

Я прошу вас помочь мне с этой проблемой:

Есть байтовый массив (data: PByte), содержащий данные DIB И DIBHeader: 


  TDibHeader = record
    size: Cardinal;
    width: Integer;
    height: Integer;
    planes: Word;
    bits: Word;
    compression: Cardinal;
    image_size: Cardinal;
    x_res: Integer;
    y_res: Integer;
    n_colors: Cardinal;
    important_colors: Cardinal;
  end;

Как преобразовать DIB в TBitmap, сохраняя низкую загрузку процессора?

Я пытался http://files.codes -sources.com / fichier.aspx? Id = 43989 & f = GdipApi.pas безуспешно.

Я назначил DIB потоку памяти: 


  DibMemStream.Clear;
  DibMemStream.SetSize(header.image_size);
  MoveMemory(DibMemStream.Memory,DibBuffer,header.image_size);

Полагаю, что где-то перед Bitmap.LoadFromMemoryStream (DibMemStream) должен быть написан заголовок DIB. Не уверен где.

Есть идеи, пожалуйста?

Спасибо!

Ответы [ 2 ]

3 голосов
/ 30 января 2010

Я использовал следующую схему для преобразования изображений в памяти в TBitmap:

1) Заполнить структуру TBMPHeader 

  TBMPHeader = packed record
    bmfHeader: TBitmapFileHeader;
    bmiHeader: TBitmapInfoHeader;
    bmiColors: {depends on image format, may be absent};
  end;

2) Записать BMPHeader + данные изображения в MemoryStream

3) Загрузить TBitmap из MemoryStream с помощью TBitmap.LoadFromStream

Кажется, вы уже заполнили структуру bmiHeader. Добавьте bmfHeader и (возможно) bmiColors.

Вот код, который я использовал для преобразования 256-цветных изображений в градациях серого в TBitmap (много лет назад, извините, так что нет подробностей): 

procedure TksImage.CopyToBitmap(Bitmap: TBitmap);
var
  Stream: TStream;

begin
  Stream:= TMemoryStream.Create;
  try
    SaveToStream(Stream);
    Stream.Position:= 0;
    Bitmap.LoadFromStream(Stream);
  finally
    Stream.Free;
  end;
end;

procedure TksImage.SaveToStream(Stream: TStream);
type
  TBMPHeader = packed record
    bmfHeader: TBitmapFileHeader;
    bmiHeader: TBitmapInfoHeader;
    bmiColors: array[0..255] of TRGBQuad;
  end;

var
  BMPHeader: TBMPHeader;
  N: LongWord;
  I: Integer;

begin
  FillChar(BMPHeader, SizeOf(BMPHeader), 0);
  with BMPHeader.bmfHeader do begin
    bfType:= $4D42; {'BM'}
    bfOffBits:= SizeOf(BMPHeader);
    if FChannels = 4 then Dec(bfOffBits, SizeOf(BMPHeader.bmiColors));
    bfSize:= bfOffBits + LongWord(FImageSize);
  end;
  with BMPHeader.bmiHeader do begin
    biSize:= SizeOf(BMPHeader.bmiHeader);
    biWidth:= FWidth;
    biHeight:= FHeight;
    biPlanes:= 1;
    biBitCount:= 8 * FChannels;
    biCompression:= BI_RGB;
    biSizeImage:= FImageSize;
    {((((biWidth * biBitCount) + 31) and not 31) shr 3) * biHeight;}
  end;
  N:= 0;
  for I:= 0 to 255 do begin
    LongWord(bmpHeader.bmiColors[I]):= N;
    Inc(N, $010101);
  end;
  Stream.Write(BMPHeader, BMPHeader.bmfHeader.bfOffBits);
  Stream.Write(FImageData^, FImageSize);
end;
0 голосов
/ 29 января 2010

Прошло много времени с тех пор, как я делал какое-либо Delphi-кодирование, и я не смог проверить это, но если вы можете предоставить дескриптор DIB, есть функция - hDIBToTBitmap1 () - которая должна помочь эта ссылка:

http://www.efg2.com/Lab/Library/Delphi/Graphics/LeadToolsConversions.TXT

...