CheckException принимает только методы с 0 параметрами; Как я могу проверить, что другие методы выдают исключения? - PullRequest
Новая
       26

CheckException принимает только методы с 0 параметрами; Как я могу проверить, что другие методы выдают исключения?

27 голосов
/ 06 января 2011

Мне интересно, как лучше проверять исключения в dunit.Я не очень знаком с указателями методов в Delphi.Есть ли возможность привязать аргументы к указателю на метод, чтобы он мог быть вызван без аргументов.На данный момент я всегда пишу дополнительный метод, который выполняет эту «привязку» вручную.Это будет раздражать, если в SUT есть много методов броска. 

// What i did before i knew abput CheckExcepion
procedure MyTest.MyMethod_BadInput_Throws;
var
    res: Boolean;
begin
    res := false;
    try
        sut.MyMethod('this is bad');
    except
        on e : MyExpectedException do:
            res := true;
    end;
    CheckTrue(res);
end;

// What i do now
procedure MyTest.MyMethodWithBadInput;
begin
    sut.MyMethod('this is bad');
end;

procedure MyTest.MyMethod_BadInput_Throws;
begin
    CheckException(MyMethodWithBadInput, MyExpectedException);
end;

// this would be nice
procedure MyTest.MyMethod_BadInput_Throws;
begin
    CheckException(
        BindArguments(sut.MyMethod, 'this is bad'),  // <-- how to do this
        MyExpectedException);
end;

Ответы [ 5 ]

43 голосов
/ 06 января 2011

Вы можете использовать StartExpectingException для окружения вашего вызова метода). 

StartExpectingException(MyException);
MyMethod(MyParam);
StopExpectingException();
3 голосов
/ 11 апреля 2011

Как уже отмечалось, это отличное место для анонимных методов.

Вот как я это делаю.Я «позаимствовал» это у Алекса Чобану: 

procedure TestTMyClass.CheckException(aExceptionType: TClassOfException; aCode: TTestCode; const aMessage: String);
var
  WasException: Boolean;
begin
  WasException := False;
  try
    aCode;
  except
    on E: Exception do
    begin
      if E is aExceptionType then
      begin
        WasException := True;
      end;
    end;
  end;
  Check(WasException, aMessage);
end;

Затем назовите это как-то так: 

CheckException(ETestingException, 
             procedure begin FMyClass.RaiseTestingException end,      
             'The ETestingException exception didn''t get raised.  That is impossible!');
3 голосов
/ 06 января 2011

Я пока не знаю, поддерживает ли DUnit его, но это идеальный вариант использования для анонимных методов, которые были представлены в Delphi 2010. Если DUnit не поддерживает его, вы можете легко изменить источник самостоятельно.

1 голос
/ 05 августа 2013

Использовать StartExpectingException() - не лучший способ, если вы хотите протестировать более одного исключения.Чтобы протестировать все возможные случаи в моей процедуре тестирования, вместе с исключениями я использую этот алгоритм: 

uses
  Dialogs;
procedure MyTest.MyMethod_Test;
begin
  // Test for Exceptions
  try
    MyMethod(MyParam1CreatingException1);
    ShowMessage('Error! There should have been exception: Exxx here!');
    Check(false);
  except on E: Exception do Check(E is  ExceptionType1); end; // This exception is OK
  try
    MyMethod(MyParam2CreatingException2);
    ShowMessage('Error! There should have been exception: Exxx here!');
    Check(false);
  except on E: Exception do Check(E is  ExceptionType2); end; // This exception is OK
  // ... test other exceptions ...

  // Test other parameters
  CheckEquals('result1', MyMethod(MyParam1));
  CheckEquals('result2', MyMethod(MyParam2));
  // ... other tests ...
end;

Причина, по которой я использую ShowMessage('Error! There should be exception: Exxx here!'); вместо предоставленного метода Check(false, 'There should have been an EListError.');, заключается в том, что в моем случае(Delphi6) Check(boolean, 'Message') не работает - он не показывает сообщение в случае, если Check находится внутри блока try...except (не знаю почему).

0 голосов
/ 17 марта 2016

Это рабочая и улучшенная версия ответа Ника Ходжеса, которая подклассов DUnit TestFramework.TTestCase: 

uses
  TestFramework, System.SysUtils;
type
  TTestCode = reference to procedure;

  TTestCasePlus = class(TestFramework.TTestCase)
    procedure CheckException(
      ExceptionType: TClass; Code: TTestCode; const Message: String = '');
  end;

implementation

procedure TTestCasePlus.CheckException(
  ExceptionType: TClass; Code: TTestCode; const Message: String = '');
{ Check whether some code raises a specific exception type.

Adapted from http://stackoverflow.com/a/5615560/797744

Example:

  Self.CheckException(EConvertError,
                      procedure begin UnformatTimestamp('invalidstr') end);

@param ExceptionType: The exception class which we check if it was raised.
@param Code: Code in the form of an anonymous method that should raise the
  exception.
@param Message: Output message on check failure. }
var
  WasRaised: Boolean;
begin
  WasRaised := False;
  try
    Code;
  except
    on E: Exception do
      if E is ExceptionType then
        WasRaised := True;
  end;
  Check(WasRaised, Message);
end;

Приятным бонусом к этому методу проверки того, было ли исключение возбуждено в течение Start/StopExpectingException(), является то, что вы можете запускать testrunner в отладочной сборке, и он не будет вас беспокоить "Возникло исключение. Перерыв? Продолжить?" каждый раз, когда возникает исключение - даже если оно было обработано.

...