xsl: как разбить строки? - PullRequest
Новая
       8

xsl: как разбить строки?

32 голосов
/ 31 января 2011

Я хочу разбить адрес на точки с запятой (;) на строки, разделенные <br />:

например, если address = 123 Elm Street, я хочу вывести 123 Elm Street,

но если address = 123 Elm Street;PO Box 222, я хочу вывести 

123 Elm Street<br />PO Box 222

, а если address = 123 Elm Street;PO Box 222;c/o James Jones, я хочу вывести 

123 Elm Street<br />PO Box 222<br />c/o James Jones

Есть ли способ сделать это?(вероятно, легко, но я не очень знаком с XSLT)

Простой селектор XSL - 

<xsl:value-of select="address"/>

, и я хотел бы изменить этот фрагмент XSLT для разделения на точку с запятой.

обновление : Очевидно, ответ включает использование <xsl:call-template> и функций substring-before() и substring-after().

Но я новичок в XSLT иЯ мог бы действительно использовать некоторую помощь, как это сделать.

Ответы [ 2 ]

62 голосов
/ 31 января 2011

I. Простое решение XSLT 1.0:

Это преобразование : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="text()" name="split">
  <xsl:param name="pText" select="."/>
  <xsl:if test="string-length($pText)">
   <xsl:if test="not($pText=.)">
    <br />
   </xsl:if>
   <xsl:value-of select=
    "substring-before(concat($pText,';'),';')"/>
   <xsl:call-template name="split">
    <xsl:with-param name="pText" select=
     "substring-after($pText, ';')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

при применении к этому документу XML : 

<t>123 Elm Street;PO Box 222;c/o James Jones</t>

дает требуемый, исправленный результат : 

123 Elm Street<br />PO Box 222<br />c/o James Jones

II. FXSL 1 (для XSLT 1.0):

Здесь мы просто используем FXSL шаблон str-map (и не должны писать рекурсивный шаблон в 999-й раз): 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/"
xmlns:testmap="testmap"
exclude-result-prefixes="xsl f testmap"
>
   <xsl:import href="str-dvc-map.xsl"/>

   <testmap:testmap/>

   <xsl:output omit-xml-declaration="yes" indent="yes"/>

   <xsl:template match="/">
     <xsl:variable name="vTestMap" select="document('')/*/testmap:*[1]"/>
     <xsl:call-template name="str-map">
       <xsl:with-param name="pFun" select="$vTestMap"/>
       <xsl:with-param name="pStr" select=
       "'123 Elm Street;PO Box 222;c/o James Jones'"/>
     </xsl:call-template>
   </xsl:template>

    <xsl:template name="replace" mode="f:FXSL"
         match="*[namespace-uri() = 'testmap']">
      <xsl:param name="arg1"/>

      <xsl:choose>
       <xsl:when test="not($arg1=';')">
        <xsl:value-of select="$arg1"/>
       </xsl:when>
       <xsl:otherwise><br /></xsl:otherwise>
      </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к любому XML-документу (не используется), получается тот же, требуемый правильный результат : 

123 Elm Street<br/>PO Box 222<br/>c/o James Jones

III. Использование XSLT 2.0 

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="text()">
  <xsl:for-each select="tokenize(.,';')">
   <xsl:sequence select="."/>
   <xsl:if test="not(position() eq last())"><br /></xsl:if>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к этому документу XML : 

<t>123 Elm Street;PO Box 222;c/o James Jones</t>

желаемый, правильный результат получается : 

123 Elm Street<br />PO Box 222<br />c/o James Jones
2 голосов
/ 31 января 2011

Если ваш XSLT-процессор поддерживает EXSLT , вы можете использовать str: tokenize , в противном случае ссылка содержит реализацию с использованием таких функций, как substring-before.

...