Как показать текст при перемещении мыши в установщике NSIS - PullRequest
Новая
       21

Как показать текст при перемещении мыши в установщике NSIS

0 голосов
/ 19 октября 2010

есть ли возможность показать некоторый описательный текст на пользовательской странице установщика NSIS, но только при наведении курсора мыши?

У меня есть проверка предварительных условий в начале программы установки, и когда один (или более) тесты не пройдены, отображается соответствующее предупреждающее сообщение. Это пользовательская страница, отображаемая перед всей установкой. Проблема в том, что слишком много сообщений (в худшем случае) и страница установщика небольшая - невозможно показать их все без наложения ... Поэтому я хотел бы отобразить только некоторые заголовки (кратко описывающие проблема) и более подробную информацию где-то ниже в выделенной области, но только тогда, когда мышь перемещается над кратким текстом. Или другое решение - создать прокручиваемую область ...

Но я не знаю, как это сделать в NSIS. Я знаю обратный вызов .onMouseOverSection, но AFAIK его можно использовать только на странице выбора раздела.

Возможно ли это сделать на странице NSIS?

Заранее спасибо.

1 Ответ

0 голосов
/ 19 октября 2010

Я не думаю, что делать это на странице instfiles - хорошая идея.Я бы пошел на пользовательскую страницу.Если вы решили использовать идею пользовательской страницы, у вас, вероятно, есть 3 варианта:

  • Создать пользовательский плагин nsis, который показывает страницу любым удобным для вас способом.
  • Создать пользовательский плагинстраница с nsDialogs и обрабатывать сообщения мыши с помощью плагина WndSubclass .
  • Использовать две страницы компонента и настроить одну из них.

В следующем примере используется третийвариант, поскольку он использует только официальные плагины nsis.

OutFile "$%temp%\test.exe"
Name "Prereq desc"
RequestExecutionLevel user
!include MUI2.nsh

!define MUI_PAGE_HEADER_TEXT "Header blablah"
!define MUI_PAGE_HEADER_SUBTEXT "subheader blablah"
!define MUI_COMPONENTSPAGE_TEXT_TOP "blablah 1"
!define MUI_COMPONENTSPAGE_TEXT_INSTTYPE " "
!define MUI_COMPONENTSPAGE_TEXT_COMPLIST " "
!define MUI_COMPONENTSPAGE_TEXT_DESCRIPTION_TITLE "blablah 4"
!define MUI_COMPONENTSPAGE_TEXT_DESCRIPTION_INFO "blablah 5"
!define MUI_PAGE_CUSTOMFUNCTION_PRE prereqcreate
!define MUI_PAGE_CUSTOMFUNCTION_SHOW prereqshow
!insertmacro MUI_PAGE_COMPONENTS

!define MUI_PAGE_CUSTOMFUNCTION_PRE componentscreate
!insertmacro MUI_PAGE_COMPONENTS

!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"

Function .onInit
InitPluginsDir
StrCpy $0 0
loop:
    ClearErrors
    SectionGetText $0 $1
    IfErrors done
    WriteIniStr "$Pluginsdir\sec.ini" S $0 $1 ;Save section names...
    IntOp $0 $0 + 1
    Goto loop
done:   
FunctionEnd

!macro ShowSections initial flip
StrCpy $0 0
StrCpy $2 ${initial}
loop:
    ClearErrors
    SectionGetText $0 $1
    IfErrors done
    ReadIniStr $1 "$Pluginsdir\sec.ini" S $0
    IntCmpU 0 $2 "" +2 +2
    StrCpy $1 ""
    SectionSetText $0 $1
    IntOp $0 $0 + 1
    IntCmpU $0 ${flip} "" +2 +2
    IntOp $2 $2 ! 
    Goto loop
done:
!macroend

!macro CreatePreReq text name
Section /o "${text}" ${name}
SectionIn RO
SectionEnd
!macroend

!insertmacro CreatePreReq "Windows Installer v4.5" SEC_PRMSI
!insertmacro CreatePreReq ".NET v666" SEC_PRDOTNET

Section "Program files" SEC_PROG
;...
SectionEnd

Section "Desktop shortcut" SEC_DESKLNK
;...
SectionEnd

!define FIRSTREALSECTION ${SEC_PROG}

Function prereqcreate
!insertmacro ShowSections 1 ${FIRSTREALSECTION}
FunctionEnd

Function prereqshow
FindWindow $0 "#32770" "" $HWNDPARENT
GetDlgItem $1 $0 0x3FD
ShowWindow $1 0 
GetDlgItem $1 $0 0x3FE
ShowWindow $1 0 
GetDlgItem $1 $0 0x3FF
ShowWindow $1 0 ;hide space texts
GetDlgItem $1 $0 0x408
!define TVM_SETIMAGELIST 0x1109
SendMessage $1 ${TVM_SETIMAGELIST} 2 0 ;Remove images (leaking the imagelist in the process, oh well)
System::Call '*(&i24)i.r2'
System::Call 'user32::GetWindowRect(ir1,ir2)'
System::Call 'user32::MapWindowPoints(i0,ir0,ir2,i2)'
System::Call '*$2(i,i.r0,i.r3,i.r4)'
System::Free $2
IntOp $4 $4 - $0
System::Call 'user32::SetWindowPos(ir1,i0,i0,ir0,ir3,ir4,i0)'
FunctionEnd

Function componentscreate
!insertmacro ShowSections 0 ${FIRSTREALSECTION}
FunctionEnd

!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC_PRMSI} "You need MSI in a NSIS installer? ;)"
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC_PRDOTNET} "You need moar bloat!"
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC_PROG} "Required program files..."
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC_DESKLNK} "Stupid desktop shortcut"
!insertmacro MUI_FUNCTION_DESCRIPTION_END
...