Преобразование шестнадцатеричной строки в ansistring в Delphi 2010 - PullRequest
Новая
       22

Преобразование шестнадцатеричной строки в ansistring в Delphi 2010

4 голосов
/ 06 марта 2011

Раньше я использовал эту функцию для преобразования шестнадцатеричной строки в строку в Delphi 6: 

const
testSign = '207F8060287F585054505357FFD55861';

function Hex2Dec(const data: string): byte;
var
  nH1, nH2: byte;
begin
  if data[1] in ['0' .. '9'] then
    nH1 := strtoint(data[1])
  else
    nH1 := 9 + ord(data[1]) - 64;
  if data[2] in ['0' .. '9'] then
    nH2 := strtoint(data[2])
  else
    nH2 := 9 + ord(data[2]) - 64;
  Result := nH1 * 16 + nH2;
end;

function HexStrToStr(const HexStr: string): string;
var
  BufStr: string;
  LenHex: Integer;
  x, y: Integer;
begin
  LenHex := Length(HexStr) div 2;
  x := 1;
  y := 0;
  while y <> LenHex do
  begin
    Inc(y);
    BufStr := BufStr + Chr(Hex2Dec(HexStr[x] + HexStr[x + 1]));
    Inc(x, 2);
  end;
  Result := BufStr;
end;

Теперь я хочу использовать функцию с Delphi 2010. 

const
testSign: AnsiString = '207F8060287F585054505357FFD55861';

function Hex2Dec(const data: ansistring): byte;
var
  nH1, nH2: byte;
begin
  if data[1] in ['0' .. '9'] then
    nH1 := strtoint(data[1])
  else
    nH1 := 9 + ord(data[1]) - 64;
  if data[2] in ['0' .. '9'] then
    nH2 := strtoint(data[2])
  else
    nH2 := 9 + ord(data[2]) - 64;
  Result := nH1 * 16 + nH2;
end;

function HexStrToStr(const HexStr: ansistring): ansistring;
var
  BufStr: ansistring;
  LenHex: Integer;
  x, y: Integer;
begin
  LenHex := Length(HexStr) div 2;
  x := 1;
  y := 0;
  while y <> LenHex do
  begin
    Inc(y);
    BufStr := BufStr + Chr(Hex2Dec(HexStr[x] + HexStr[x + 1]));
    Inc(x, 2);
  end;
  Result := BufStr;
end;

Вывод изпервый код в D6: 

' '#$7F'€`('#$7F'XPTPSWÿÕXa'

Вывод из второго кода в D2010: 

' '#$7F#$0080'`('#$7F'XPTPSWÿÕXa'

Как исправить код в D2010, чтобы он мог давать такой же результат, как D6?

1 Ответ

7 голосов
/ 06 марта 2011

Помимо решений, предоставленных другими, вы также можете использовать встроенную функцию: 

function HexStrToStr(const HexStr: string): string;
var
  tmp: AnsiString;
begin
  Assert(not Odd(Length(HexStr)), 'HexToStr input length must be an even number');
  SetLength(tmp, Length(HexStr) div 2);
  HexToBin(PWideChar(HexStr), @tmp[1], Length(tmp));
  result := tmp;
end;

Эта реализация предполагает, что строка в шестнадцатеричном коде была Ansistring в первую очередь. Для большей гибкости я предлагаю использовать TBytes .

...