Растровые данные .draw () с матрицей преобразования - PullRequest
Новая
       23

Растровые данные .draw () с матрицей преобразования

0 голосов
/ 29 июня 2011

Я работаю над проектом, в котором пользователь может сделать снимок себя с помощью своей веб-камеры, а затем отредактировать это изображение, изменив масштаб и поворот и сохранив результат.

У меня есть большая его частьработая, пользователь может сделать снимок себя, преобразовать объект, используя инструмент преобразования Senocular, и я использую .draw (), чтобы затем сохранить этот преобразованный объект.Проблема в том, что .draw () собирает данные только из верхнего левого угла сцены.Он рисует преобразованный объект, но только из верхнего левого угла.

Почему он рисует только из верхнего левого угла и как я могу установить координаты, чтобы рисовать только из области, где установлено захваченное изображение?

Спасибо.

Вы можете просмотреть файл как есть: http://s46264.gridserver.com/dev/dave/pb-photo/index.html

И я заархивировал FLA и соответствующие классы на http://s46264.gridserver.com/dev/dave/pb-photo/pb-photo.zip

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.Sprite;
import flash.geom.Matrix;
import flash.net.FileReference;
import com.adobe.images.JPGEncoder;
import com.senocular.display.transform.*;

// create container for captured image to apply Transform Tool to
var box:Sprite = new Sprite();
addChild(box);
box.graphics.beginFill(0xAACCDD);
box.graphics.drawRect(-160, -120, 320, 240); // xreg, yreg, width, height (x-y = width-height / 2 to set centered registration point)
box.x = 520;
box.y = 140;

// create the Transform Tool
var tool:TransformTool = new TransformTool(new ControlSetStandard());
addChild(tool);

// select the box with the transform tool when clicked. 
// deselect when clicking on the stage
box.addEventListener(MouseEvent.MOUSE_DOWN, tool.select);
stage.addEventListener(MouseEvent.MOUSE_DOWN, tool.deselect);

var snd:Sound = new camerasound(); //new sound instance for the "capture" button click

var bandwidth:int = 0; // Maximum amount of bandwidth that the current outgoing video feed can use, in bytes per second.
var quality:int = 100; // This value is 0-100 with 1 being the lowest quality. 

var cam:Camera = Camera.getCamera();
cam.setQuality(bandwidth, quality);
cam.setMode(320,240,30,false); // setMode(videoWidth, videoHeight, video fps, favor area)
var video:Video = new Video();
video.attachCamera(cam);
video.x = 20;
video.y = 20;
addChild(video);

// create bitmap to hold initial capture and addChild to transform box
var bitmapData:BitmapData = new BitmapData(video.width,video.height);

var bitmap:Bitmap = new Bitmap(bitmapData);
bitmap.x = -160;
bitmap.y = -120;
box.addChild(bitmap);

capture_mc.buttonMode = true;
capture_mc.addEventListener(MouseEvent.CLICK,captureImage);

function captureImage(e:MouseEvent):void {
    snd.play();
    bitmapData.draw(video);
    save_mc.buttonMode = true;
    save_mc.addEventListener(MouseEvent.CLICK, onSaveJPG);
    save_mc.alpha = 1;
}

save_mc.alpha = .5;

// save transformed bmp to new object and addChild to holder_mc
function onSaveJPG(e:Event):void{

    var m:Matrix = box.transform.matrix;
    trace(m);

    var bmp:BitmapData = new BitmapData(320, 240, true, 0xCCCCCCCC);
    bmp.draw(box, m);

    var newbmp:Bitmap = new Bitmap(bmp);
    holder_mc.addChild(newbmp);

}

Ответы [ 3 ]

5 голосов
/ 29 июня 2011

Как ни странно, я сейчас работаю над чем-то очень похожим. Вы можете нарисовать определенную область вашей цели, передав смещения по осям x и y как часть матрицы: 

var bmd:BitmapData = new BitmapData(target.width,target.height,true,0);
var mat:Matrix = new Matrix(1,0,0,1,-target.x,-target.y);
bmd.draw(this,mat);

Обратите внимание, в частности, что x и y, переданные в матрицу, устанавливаются отрицательными.

3 голосов
/ 29 июня 2011

Вы можете нарисовать всю сцену, а затем выбрать нужные пиксели, используя copyPixels (). Метод показан ниже:) 

private function drawImage():void
{
    var bmp:BitmapData = new BitmapData(stage.stageWidth, stage.stageHeight)
    bmp.draw(stage);

    var _newBmp:BitmapData = new bitmapData(WidthOfTheImage, HeightOfTheImage, TransParancy, FillColor);
    _newBmp.copyPixels(bmp, new Rectangle(XofTheImage, YOftheImage, WidthOfTheImage, HeightOfTheImage), new point());
}

_newBmp - это требуемые точечные рисунки:)

0 голосов
/ 11 августа 2012

Получение границ клипа даст вам точную область, которую вы хотите скопировать. 

var bounds:Rectangle = mc.getBounds(mc);
var bitmapData:BitmapData = new BitmapData(int(bounds.width + 0.5), int(bounds.height + 0.5), true, 0);
bitmapData.draw(mc, new Matrix(1, 0, 0, 1, -bounds.x, -bounds.y));
...