Xslt группа родитель / ребенок - PullRequest
Новая
       9

Xslt группа родитель / ребенок

3 голосов
/ 30 апреля 2011

У меня проблема с получением следующего результата от преобразования xml / xslt: 

<root>
  <node>   
    <id>1</id>
    <parentid></parentid>
    <name>file 1</name>
  <node>
  <node>   
    <id>2</id>
    <parentid></parentid>
    <name>file 2</name>
  <node>
  <node>   
    <id>3</id>
    <parentid>2</parentid>
    <name>file 3</name>
  <node>
  <node>   
    <id>4</id>
    <parentid></parentid>
    <name>file 4</name>
  <node>
  <node>   
    <id>5</id>
    <parentid>2</parentid>
    <name>file 5</name>
  <node>
</root>

Я хотел бы, чтобы выходной html был примерно таким:

Ответы [ 2 ]

2 голосов
/ 30 апреля 2011

Ключ (без каламбура) состоит в том, чтобы использовать <xsl:key> для установки отношения родитель-ребенок. Как только это определено, остальное легко. 

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes"/>

    <xsl:key name="getchildren" match="node" use="parentid"/>

    <xsl:template match="root">
        <ul>
            <xsl:apply-templates
              select="node[parentid[not(normalize-space())]]"/>
        </ul>
    </xsl:template>

    <xsl:template match="node">
        <li><xsl:value-of select="name"/></li>
        <xsl:variable name="children" select="key( 'getchildren', id )"/>
        <xsl:if test="$children">
            <ul><xsl:apply-templates select="$children"/></ul>
        </xsl:if>
    </xsl:template>

</xsl:stylesheet>
2 голосов
/ 30 апреля 2011 
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:strip-space elements="*"/>

    <xsl:template match="/root">
        <ul>
            <xsl:apply-templates select="node[string-length(parentid)=0]" />
        </ul>
    </xsl:template>

    <xsl:template match="node">
        <li>
            <xsl:value-of select="name"/>
        </li>
        <xsl:variable name="children" select="parent::*/node[parentid=current()/id]" />
        <xsl:if test="$children">
            <ul>
                <xsl:apply-templates select="$children" />
            </ul>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>
...