NSiS вызывает функцию для выгрузки файла журнала в конце установки - PullRequest
Новая
       14

NSiS вызывает функцию для выгрузки файла журнала в конце установки

2 голосов
/ 07 января 2012

я работаю над проектом, в котором я использую NSI для создания установки myproject.exe , все работает нормально, но я хочу вывести журнал, который отображается в файл, который также работает нормально, но моя проблема в том, что я не могу понять, когда вызывать функцию журнала

У меня есть 12 разделов в моем скрипте, я получил функцию создания журнала установки из Журнал дампов в файл 

 !define PRODUCT_NAME "myApplication"
 !define PRODUCT_VERSION "1.7.1"
 !define LVM_GETITEMCOUNT 0x1004
 !define LVM_GETITEMTEXT 0x102D
 !include MUI2.nsh


  Name "myExe"
  OutFile "C:\myExe.exe"

  InstallDir $PROGRAMFILES\myprojc
  InstallDirRegKey HKCU "Software\myprojc" "Install_Dir"

  !define MUI_ABORTWARNING      
  !define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\Folder-Options.ico"
  !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\orange-uninstall.ico"
  !define MUI_HEADERIMAGE
  !define MUI_HEADERIMAGE_BITMAP "${NSISDIR}\Contrib\Graphics\Header\Banner.bmp" 

    ; Pages

  !insertmacro MUI_PAGE_WELCOME
  !insertmacro MUI_PAGE_COMPONENTS
  !insertmacro MUI_PAGE_DIRECTORY
  !insertmacro MUI_PAGE_INSTFILES

   !insertmacro MUI_UNPAGE_WELCOME
  !insertmacro MUI_UNPAGE_CONFIRM
  !insertmacro MUI_UNPAGE_INSTFILES
  !insertmacro MUI_UNPAGE_FINISH

    ;Languages

 !insertmacro MUI_LANGUAGE "English"
 BrandingText "myProj version 1.7.1"

 ;Here My section are decribed.. 12 of them
 Section "main program and components" section1
     ;main promgram files are copied

 SectionEnd

 Section "other DLL" section2
 ;copy the DLLs
 SectionEnd

 Section "Text files" section3
 ;copy the required txt files
 SectionEnd

  ;-....
  ;...

 Section "install BDE admin" section12
  ;copy install BDE admin

    ;Calling the Dumplog function to create the log file
     StrCpy $0 "$INSTDIR\Query\Presleyinstall.log"
     Push $0
     Call DumpLog
 SectionEnd


;The function dumps the to a log file
 Function DumpLog
 Exch $5
 Push $0
 Push $1
 Push $2
 Push $3
 Push $4
 Push $6

 FindWindow $0 "#32770" "" $HWNDPARENT
 GetDlgItem $0 $0 1016
StrCmp $0 0 exit
FileOpen $5 $5 "w"
StrCmp $5 "" exit
SendMessage $0 ${LVM_GETITEMCOUNT} 0 0 $6
System::Alloc ${NSIS_MAX_STRLEN}
Pop $3
StrCpy $2 0
System::Call "*(i, i, i, i, i, i, i, i, i) i \
  (0, 0, 0, 0, 0, r3, ${NSIS_MAX_STRLEN}) .r1"
loop: StrCmp $2 $6 done
  System::Call "User32::SendMessageA(i, i, i, i) i \
    ($0, ${LVM_GETITEMTEXT}, $2, r1)"
  System::Call "*$3(&t${NSIS_MAX_STRLEN} .r4)"
  FileWrite $5 "$4$\r$\n"
  IntOp $2 $2 + 1
  Goto loop
done:
  FileClose $5
  System::Free $1
  System::Free $3
exit:
  Pop $6
  Pop $4
  Pop $3
  Pop $2
  Pop $1
   Pop $0
  Exch $5
FunctionEnd

Так как я вызвал функцию dumplog в секции 12 , файл журнала only создает, когда / если секция выбрана пользователем, если раздел 12 не выбран, тогда функция дампа не будет вызвана, и файл журнала не будет создан,

поэтому, пожалуйста, скажите мне, как я могу вызвать функцию dumplog независимо от того, выбран ли раздел пользователем или нет, то есть вызвать dumplog, когда установка завершена.

EDIT

я также могу попытаться создать раздел «Создать журнал установщика», проверить его и отключить, как 

 Section "Create installer log" section13
 SectionIn RO
 StrCpy $0 "$INSTDIR\myinstall.log"
 Push $0
 Call DumpLog
 SectionEnd

это enter image description here

но есть ли способ вызвать функцию dumplog без раздела и в конце установки?

Ответы [ 2 ]

2 голосов
/ 07 января 2012

Если вы не дадите названию раздела (или начнете имя с -), то оно не будет отображаться на странице компонентов: 

Section "Foobar"
;Install the optional Foobar
SectionEnd

Section
;Hidden section
Section
1 голос
/ 28 января 2016

Вы даже можете поместить его в функции обратного вызова. 

Function .onInstSuccess
;..
Call DumpLog
;..
FunctionEnd

Function .onInstFail
;..
Call DumpLog
;..
FunctionEnd
...