Как я могу запросить несколько столбцов из выпадающего меню и счет определенного столбца

Question

Я пытаюсь создать отчет для пользователя, чтобы выбрать из раскрывающегося меню. Я хотел бы иметь возможность получить несколько столбцов из выбранного раскрывающегося списка. И, если возможно, получить определенный счет для определенного столбца.

Пока мне удалось выбрать только один столбец и получить из него счетчик.

=QUERY(A2:O20,"SELECT M, count(M) Where E ='" &B23 & "' group by M",0)

Я бы хотел как-то продолжить выделение определенных столбцов и отображать их, когда пользователь выбирает из выпадающего меню, а также сохранять мою текущую работу (Счет от M)

Answer 1

компактный режим:

={"select Interface", L1;
 QUERY(A2:H, "select A,count(A) where D='"&L1&"' group by A label count(A)''");
 QUERY(A2:H, "select B,count(B) where D='"&L1&"' group by B label count(B)''");
 QUERY(A2:H, "select C,count(C) where D='"&L1&"' group by C label count(C)''");
 QUERY(A2:H, "select E,count(E) where D='"&L1&"' group by E label count(E)''");
 QUERY(A2:H, "select F,count(F) where D='"&L1&"' group by F label count(F)''");
 QUERY(A2:H, "select G,count(G) where D='"&L1&"' group by G label count(G)''");
 QUERY(A2:H, "select H,count(H) where D='"&L1&"' group by H label count(H)''")}

---

с маркировкой:

=IF(K1<>"", {
 QUERY(A1:H, "select A,count(A) where D='"&K1&"' group by A label count(A)''", 1);
 QUERY(A1:H, "select B,count(B) where D='"&K1&"' group by B label count(B)''", 1);
 QUERY(A1:H, "select C,count(C) where D='"&K1&"' group by C label count(C)''", 1);
 QUERY(A1:H, "select E,count(E) where D='"&K1&"' group by E label count(E)''", 1);
 QUERY(A1:H, "select F,count(F) where D='"&K1&"' group by F label count(F)''", 1);
 QUERY(A1:H, "select G,count(G) where D='"&K1&"' group by G label count(G)''", 1);
 QUERY(A1:H, "select H,count(H) where D='"&K1&"' group by H label count(H)''", 1)}, )

примечание: зеленый фон и полужирные метки могут быть автоматически установлены с помощью условного форматирования

---

расширенный режим:

=ARRAYFORMULA(REGEXREPLACE(TO_TEXT(QUERY(A1:H, 
 "select A,count(A),B,count(B),C,count(C),D,count(D),
         E,count(E),F,count(F),G,count(G),H,count(H) 
  where D='"&K1&"' 
  group by A,B,C,D,E,F,G,H", 1)), "^count.*", ""))

Answer 2

Я настроил копию вашего листа, в которой счетчик каждого столбца составляется в виде отчета на основе того, какое значение выбрано из выпадающего списка.Формула находится в ячейке K1, и я переместил раскрывающийся список в ячейку J1:

https://docs.google.com/spreadsheets/d/1ccFgll7mW2rNs6m9gHUAx7ObsZ8n4GFjMc2cZS0nX68/edit?usp=sharing

Синтаксис формулы использует;чтобы разместить каждый вывод QUERY поверх следующего:

={QUERY(ColA);QUERY(ColB);QUERY(ColC);QUERY(ColE) etc...}