Решение векторных уравнений в Mathematica

Question

Я пытаюсь выяснить, как использовать Mathematica для решения систем уравнений, где некоторые переменные и коэффициенты являются векторами. Простым примером будет что-то вроде

где я знаю A , V и величину P , и я должен решить для t и направление П. (В основном, учитывая два луча А и В, где я знаю все об А, но только происхождение и величину В, выясните, какое направление В должно быть таким, чтобы оно пересекало А.)

Теперь я знаю, как решать подобные вещи вручную, но это медленно и подвержено ошибкам, поэтому я надеялся, что смогу использовать Mathematica для ускорения и проверки ошибок. Однако я не понимаю, как заставить Mathematica символически решать уравнения с такими векторами.

Я посмотрел в пакете VectorAnalysis, не найдя там ничего, что кажется уместным; в то же время пакет линейной алгебры, кажется, имеет решатель только для линейных систем (что не так, поскольку я не знаю t или P , просто | P | ).

Я пытался сделать простую вещь: расширить векторы на их компоненты (притвориться, что они 3D) и решить их, как будто я пытался приравнять две параметрические функции,

Solve[ 
      { Function[t, {Bx + Vx*t, By + Vy*t, Bz + Vz*t}][t] == 
          Function[t, {Px*t, Py*t, Pz*t}][t],
        Px^2 + Py^2 + Pz^2 == Q^2 } , 
      { t, Px, Py, Pz } 
     ]

но «решение», которое выплевывает, это огромный беспорядок в коэффициентах и ​​заторах. Это также вынуждает меня расширять каждое измерение, которым я питаюсь.

То, что я хочу, - это хорошее символическое решение с точки зрения точечных, перекрестных и норм:

Но я не вижу, как сказать Solve, что некоторые коэффициенты являются векторами, а не скалярами.

Возможно ли это? Может ли Mathematica дать мне символические решения для векторов? Или я должен просто придерживаться технологии № 2 Карандаш?

(Просто чтобы прояснить, мне не интересно решение конкретного уравнения сверху - я спрашиваю, могу ли я использовать Mathematica для решения таких задач вычислительной геометрии, как правило, без необходимости выражать все как явная матрица {Ax, Ay, Az} и т. д.)

Answer 1

---

С Mathematica 7.0.1.0

Clear[A, V, P];
A = {1, 2, 3};
V = {4, 5, 6};
P = {P1, P2, P3};
Solve[A + V t == P, P]

выходы:

{{P1 -> 1 + 4 t, P2 -> 2 + 5 t, P3 -> 3 (1 + 2 t)}}

Вывод P = {P1, P2, P3} может раздражать, если массив или матрица велики.

Clear[A, V, PP, P];
A = {1, 2, 3};
V = {4, 5, 6};
PP = Array[P, 3];
Solve[A + V t == PP, PP]

выходы:

{{P[1] -> 1 + 4 t, P[2] -> 2 + 5 t, P[3] -> 3 (1 + 2 t)}}

Матричное векторное внутреннее произведение:

Clear[A, xx, bb];
A = {{1, 5}, {6, 7}};
xx = Array[x, 2];
bb = Array[b, 2];
Solve[A.xx == bb, xx]

выходы:

{{x[1] -> 1/23 (-7 b[1] + 5 b[2]), x[2] -> 1/23 (6 b[1] - b[2])}}

Умножение матриц:

Clear[A, BB, d];
A = {{1, 5}, {6, 7}};
BB = Array[B, {2, 2}];
d = {{6, 7}, {8, 9}};
Solve[A.BB == d]

* * 1 022 Выходы: * +1023 *

{{B[1, 1] -> -(2/23), B[2, 1] -> 28/23, B[1, 2] -> -(4/23), B[2, 2] -> 33/23}}

Точечный продукт имеет встроенную систему обозначений, просто используйте точку для точки.

Однако я не думаю, что перекрестный продукт делает. Вот как вы используете пакет Notation для создания пакета. «Х» станет нашей инфиксной формой Креста. Я предлагаю скопировать пример из учебника по Notation, Symbolize и InfixNotation. Также используйте палитру обозначений, которая помогает абстрагироваться от некоторого синтаксиса Box.

Clear[X]
Needs["Notation`"]
Notation[x_ X y_\[DoubleLongLeftRightArrow]Cross[x_, y_]]
Notation[NotationTemplateTag[
  RowBox[{x_,  , X,  , y_,  }]] \[DoubleLongLeftRightArrow] 
  NotationTemplateTag[RowBox[{ , 
RowBox[{Cross, [, 
RowBox[{x_, ,, y_}], ]}]}]]]
{a, b, c} X {x, y, z}

выходы: * * тысяча тридцать-один

{-c y + b z, c x - a z, -b x + a y}

Выше выглядит ужасно, но при использовании палитры обозначений это выглядит так:

Clear[X]
Needs["Notation`"]
Notation[x_ X y_\[DoubleLongLeftRightArrow]Cross[x_, y_]]
{a, b, c} X {x, y, z}

Я сталкивался с некоторыми причудами, используя пакет обозначений в предыдущих версиях mathematica, поэтому будьте осторожны.

Answer 2

У меня нет какого-либо общего решения для вас (возможно, лучше использовать MathForum), но есть несколько советов, которые я могу вам предложить. Первый заключается в том, чтобы сделать разложение ваших векторов на компоненты более систематическим способом. Например, я бы решил уравнение, которое вы написали, следующим образом.

rawSol = With[{coords = {x, y, z}},
  Solve[
    Flatten[
     {A[#] + V[#] t == P[#] t & /@ coords,
     Total[P[#]^2 & /@ coords] == P^2}],
    Flatten[{t, P /@ coords}]]];

Тогда вы можете работать с переменной rawSol проще. Далее, поскольку вы обращаетесь к компонентам вектора единообразным образом (всегда совпадающим с шаблоном Mathematica v_[x|y|z]), вы можете определить правила, которые помогут упростить их. Я немного поиграл, прежде чем придумал следующие правила:

vectorRules =
  {forms___ + vec_[x]^2 + vec_[y]^2 + vec_[z]^2 :> forms + vec^2,
   forms___ + c_. v1_[x]*v2_[x] + c_. v1_[y]*v2_[y] + c_. v1_[z]*v2_[z] :>
     forms + c v1\[CenterDot]v2};

Эти правила упростят отношения для векторных норм и точечных произведений (перекрестные произведения оставляются читателю как наиболее болезненное упражнение). РЕДАКТИРОВАТЬ: rcollyer указал, что вы можете сделать c необязательным в правиле для точечных продуктов, поэтому вам нужно только два правила для норм и точечных продуктов.

С этими правилами я сразу смог упростить решение для t в форме, очень близкой к вашей:

  In[3] := t /. rawSol //. vectorRules // Simplify // InputForm
  Out[3] = {(A \[CenterDot] V - Sqrt[A^2*(P^2 - V^2) + 
                                   (A \[CenterDot] V)^2])/(P^2 - V^2), 
            (A \[CenterDot] V + Sqrt[A^2*(P^2 - V^2) + 
                                   (A \[CenterDot] V)^2])/(P^2 - V^2)}

Как я уже сказал, это не полный способ решения подобных проблем любыми способами, но если вы осторожны в приведении проблемы к терминам, с которыми легко работать с точки зрения сопоставления с образцом и замены правила , вы можете пойти довольно далеко.

Answer 3

Я принял несколько иной подход к этому вопросу. Я сделал несколько определений, которые возвращают этот вывод: Шаблоны, которые, как известно, являются векторными величинами, могут быть указаны с использованием vec[_], шаблоны с оберткой OverVector[] или OverHat[] (символы с вектором или шляпкой над ними) по умолчанию считаются векторами.

Определения являются экспериментальными и должны рассматриваться как таковые, но, похоже, они хорошо работают. Я ожидаю добавить к этому со временем.

Вот определения. Нужно вставить их в ячейку Mathematica Notebook и преобразовать в StandardForm, чтобы правильно их увидеть.

Unprotect[vExpand,vExpand$,Cross,Plus,Times,CenterDot];

(* vec[pat] determines if pat is a vector quantity.
vec[pat] can be used to define patterns that should be treated as vectors.
Default: Patterns are assumed to be scalar unless otherwise defined *)
vec[_]:=False;

(* Symbols with a vector hat, or vector operations on vectors are assumed to be vectors *)
vec[OverVector[_]]:=True;
vec[OverHat[_]]:=True;

vec[u_?vec+v_?vec]:=True;
vec[u_?vec-v_?vec]:=True;
vec[u_?vec\[Cross]v_?vec]:=True;
vec[u_?VectorQ]:=True;

(* Placeholder for matrix types *)
mat[a_]:=False;

(* Anything not defined as a vector or matrix is a scalar *)
scal[x_]:=!(vec[x]\[Or]mat[x]);
scal[x_?scal+y_?scal]:=True;scal[x_?scal y_?scal]:=True;

(* Scalars times vectors are vectors *)
vec[a_?scal u_?vec]:=True;
mat[a_?scal m_?mat]:=True;

vExpand$[u_?vec\[Cross](v_?vec+w_?vec)]:=vExpand$[u\[Cross]v]+vExpand$[u\[Cross]w];
vExpand$[(u_?vec+v_?vec)\[Cross]w_?vec]:=vExpand$[u\[Cross]w]+vExpand$[v\[Cross]w];
vExpand$[u_?vec\[CenterDot](v_?vec+w_?vec)]:=vExpand$[u\[CenterDot]v]+vExpand$[u\[CenterDot]w];
vExpand$[(u_?vec+v_?vec)\[CenterDot]w_?vec]:=vExpand$[u\[CenterDot]w]+vExpand$[v\[CenterDot]w];

vExpand$[s_?scal (u_?vec\[Cross]v_?vec)]:=Expand[s] vExpand$[u\[Cross]v];
vExpand$[s_?scal (u_?vec\[CenterDot]v_?vec)]:=Expand[s] vExpand$[u\[CenterDot]v];

vExpand$[Plus[x__]]:=vExpand$/@Plus[x];
vExpand$[s_?scal,Plus[x__]]:=Expand[s](vExpand$/@Plus[x]);
vExpand$[Times[x__]]:=vExpand$/@Times[x];

vExpand[e_]:=e//.e:>Expand[vExpand$[e]]

(* Some simplification rules *)
(u_?vec\[Cross]u_?vec):=\!\(\*OverscriptBox["0", "\[RightVector]"]\);
(u_?vec+\!\(\*OverscriptBox["0", "\[RightVector]"]\)):=u;
0v_?vec:=\!\(\*OverscriptBox["0", "\[RightVector]"]\);

\!\(\*OverscriptBox["0", "\[RightVector]"]\)\[CenterDot]v_?vec:=0;
v_?vec\[CenterDot]\!\(\*OverscriptBox["0", "\[RightVector]"]\):=0;

(a_?scal u_?vec)\[Cross]v_?vec :=a u\[Cross]v;u_?vec\[Cross](a_?scal v_?vec ):=a u\[Cross]v;
(a_?scal u_?vec)\[CenterDot]v_?vec :=a u\[CenterDot]v;
u_?vec\[CenterDot](a_?scal v_?vec) :=a u\[CenterDot]v;

(* Stealing behavior from Dot *)
Attributes[CenterDot]=Attributes[Dot];

Protect[vExpand,vExpand$,Cross,Plus,Times,CenterDot];