cooperative_groups :: this_grid () заставляет любой вызов API CUDA возвращать «неизвестную ошибку»

Question

Выполнение тех же шагов в CUDA samples для запуска ядра и синхронизации по сетке с использованием cooperative_groups::this_grid().sync() приводит к сбою любого вызова API CUDA.При использовании cooperative_groups::this_thread_block().sync() работает нормально и дает правильные результаты.

Я использовал следующий код и CMakeLists.txt (cmake версия 3.11.1), чтобы проверить его с помощью CUDA 10 на графическом процессоре TITAN V (версия драйвера 410.73) сUbuntu 16.04.5 LTS.Код также доступен на github , чтобы упростить воспроизведение ошибки.

Код читает массив, а затем переворачивает его (от [0 1 2 ... 9] до [9 8 7 ... 0]).Для этого каждый поток считывает отдельный элемент из массива, синхронизирует и затем записывает свой элемент в нужное место назначения.Код можно легко изменить, чтобы гарантировать, что this_thread_block().sync() работает нормально.Просто измените arr_size на 1024 и используйте cg::thread_block barrier = cg::this_thread_block();.

test_cg.cu

#include <cuda_runtime_api.h>
#include <stdio.h>
#include <stdint.h>
#include <cstdint>
#include <numeric>
#include <cuda.h>
#include <cooperative_groups.h>
namespace cg = cooperative_groups;

//********************** CUDA_ERROR
inline void HandleError(cudaError_t err, const char *file, int line) {
    //Error handling micro, wrap it around function whenever possible
    if (err != cudaSuccess) {
        printf("\n%s in %s at line %d\n", cudaGetErrorString(err), file, line);

#ifdef _WIN32
        system("pause");
#else
        exit(EXIT_FAILURE);
#endif
    }
}
#define CUDA_ERROR( err ) (HandleError( err, __FILE__, __LINE__ ))
//******************************************************************************


//********************** cg kernel 
__global__ void testing_cg_grid_sync(const uint32_t num_elements,
    uint32_t *d_arr){
    uint32_t tid = threadIdx.x + blockDim.x*blockIdx.x;

    if (tid < num_elements){

        uint32_t my_element = d_arr[tid];

        //to sync across the whole grid 
        cg::grid_group barrier = cg::this_grid();

        //to sync within a single block 
        //cg::thread_block barrier = cg::this_thread_block();

        //wait for all reads 
        barrier.sync();

        uint32_t tar_id = num_elements - tid - 1;

        d_arr[tar_id] = my_element;
    }
}
//******************************************************************************


//********************** execute  
void execute_test(const int sm_count){

    //host array 
    const uint32_t arr_size = 1 << 20; //1M 
    uint32_t* h_arr = (uint32_t*)malloc(arr_size * sizeof(uint32_t));
    //fill with sequential numbers
    std::iota(h_arr, h_arr + arr_size, 0);

    //device array 
    uint32_t* d_arr;
    CUDA_ERROR(cudaMalloc((void**)&d_arr, arr_size*sizeof(uint32_t)));
    CUDA_ERROR(cudaMemcpy(d_arr, h_arr, arr_size*sizeof(uint32_t),
        cudaMemcpyHostToDevice));

    //launch config
    const int threads = 512;

    //following the same steps done in conjugateGradientMultiBlockCG.cu 
    //cuda sample to launch kernel that sync across grid 
    //https://github.com/NVIDIA/cuda-samples/blob/master/Samples/conjugateGradientMultiBlockCG/conjugateGradientMultiBlockCG.cu#L436

    int num_blocks_per_sm = 0;
    CUDA_ERROR(cudaOccupancyMaxActiveBlocksPerMultiprocessor(&num_blocks_per_sm,
        (void*)testing_cg_grid_sync, threads, 0));

    dim3 grid_dim(sm_count * num_blocks_per_sm, 1, 1), block_dim(threads, 1, 1);

    if(arr_size > grid_dim.x*block_dim.x){
         printf("\n The grid size (numBlocks*numThreads) is less than array size.\n");
         exit(EXIT_FAILURE);
    }
    printf("\n Launching %d blocks, each containing %d threads", grid_dim.x,
        block_dim.x);

    //argument passed to the kernel     
    void *kernel_args[] = {
        (void *)&arr_size,
        (void *)&d_arr, };


    //finally launch the kernel 
    cudaLaunchCooperativeKernel((void*)testing_cg_grid_sync,
        grid_dim, block_dim, kernel_args);


    //make sure everything went okay
    CUDA_ERROR(cudaGetLastError());
    CUDA_ERROR(cudaDeviceSynchronize());


    //get results on the host 
    CUDA_ERROR(cudaMemcpy(h_arr, d_arr, arr_size*sizeof(uint32_t),
        cudaMemcpyDeviceToHost));

    //validate 
    for (uint32_t i = 0; i < arr_size; i++){
        if (h_arr[i] != arr_size - i - 1){
            printf("\n Result mismatch in h_arr[%u] = %u\n", i, h_arr[i]);
            exit(EXIT_FAILURE);
        }
    }
}
//******************************************************************************

int main(int argc, char**argv) {

    //set to Titan V
    uint32_t device_id = 0;
    cudaSetDevice(device_id);

    //get sm count 
    cudaDeviceProp devProp;
    CUDA_ERROR(cudaGetDeviceProperties(&devProp, device_id));
    int sm_count = devProp.multiProcessorCount;

    //execute 
    execute_test(sm_count);

    printf("\n Mission accomplished \n");
    return 0;
}

CMakeLists.txt

cmake_minimum_required(VERSION 3.8 FATAL_ERROR)

set(PROJECT_NAME "test_cg")
project(${PROJECT_NAME} LANGUAGES CXX CUDA)  

#default build type is Release
if (CMAKE_BUILD_TYPE STREQUAL "")
    set(CMAKE_BUILD_TYPE Release)
endif ()

SET(CUDA_SEPARABLE_COMPILATION ON)

########## Libraries/flags Starts Here ######################
find_package(CUDA REQUIRED)
include_directories("${CUDA_INCLUDE_DIRS}")
set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS}; -lineinfo; -std=c++11; -expt-extended-lambda; -O3; -use_fast_math; -rdc=true;)
set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS};-gencode=arch=compute_70,code=sm_70) #for TITAN V
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -m64 -Wall -std=c++11")
########## Libraries/flags Ends Here ######################


########## inc/libs/exe/features Starts Here ######################
set(CMAKE_INCLUDE_CURRENT_DIR ON)
CUDA_ADD_EXECUTABLE(${PROJECT_NAME} test_cg.cu)
target_compile_features(${PROJECT_NAME} PUBLIC cxx_std_11)
set_target_properties(${PROJECT_NAME} PROPERTIES POSITION_INDEPENDENT_CODE  ON)
set_target_properties(${PROJECT_NAME} PROPERTIES CUDA_SEPARABLE_COMPILATION ON)    
target_link_libraries(${PROJECT_NAME} ${CUDA_LIBRARIES} ${CUDA_cudadevrt_LIBRARY})
########## inc/libs/exe/features Ends Here ######################

Запуск этого кода дает:

unknown error in /home/ahdhn/test_cg/test_cg.cu at line 67

Это первая строка, которая использует cudaMalloc.Я удостоверился, что код скомпилирован для правильной архитектуры, запросив __CUDA_ARCH__ с устройства, и результат равен 700. Пожалуйста, дайте мне знать, если вы заметили, что я делаю что-то не так в коде или файле CMakeLists.txt.

Answer 1

С внешней помощью решение, которое заставило код работать, состоит в добавлении string(APPEND CMAKE_CUDA_FLAGS " -gencode arch=compute_70,code=sm_70 --cudart shared") после второго set(CUDA_NVCC_FLAGS......Причина в том, что у меня libcudadevrt.a только под моим /usr/local/cuda-10.0/lib64/, и поэтому я должен сигнализировать CUDA для связывания совместно используемой / динамической библиотеки времени выполнения, поскольку по умолчанию это ссылка на статический. string(APPEND CMAKE_CUDA_FLAGS " -gencode arch=compute_70,code=sm_70") после второго set(CUDA_NVCC_FLAGS......Причина в том, что флаг sm_70 не был передан компоновщику должным образом.

Кроме того, использование только CUDA_NVCC_FLAGS только передаст информацию sm_70 компилятору, а не компоновщику.Пока только использование CMAKE_NVCC_FLAGS сообщит об ошибке error: namespace "cooperative_groups" has no member "grid_group".