Глсл мод против Хлсл фмод - PullRequest
Новая
       49

Глсл мод против Хлсл фмод

13 голосов
/ 30 сентября 2011

Я реализовал спиральный шейдер GLSL, описанный в в этом вопросе в HLSL, но результаты не совпадают. Я думаю, что это из-за функции mod в GLSL, которую я перевел на fmod в HLSL. Я подозреваю, что эта проблема возникает, только когда у нас есть отрицательные числа на входе функции fmod.

Я попытался заменить вызов mod на вызов функции, которую я сделал, которая выполняет действия, описанные в документации GLSL , и работает:

mod возвращает значение x по модулю y. Это вычисляется как x - y * floor(x/y).

Рабочий код, который я использую вместо fmod: 

float mod(float x, float y)
{
  return x - y * floor(x/y)
}

В отличие от GLSL mod, MSDN сообщает: функция HLSL fmod делает это:

Остаток с плавающей точкой вычисляется так, что x = i * y + f, где i является целым числом, f имеет тот же знак, что и x, а абсолютное значение f меньше абсолютного значения y.

Я использовал преобразователь HLSL в GLSL , а функция fmod переводится как mod. Тем не менее, я не знаю, могу ли я предположить, что mod означает fmod.

Вопросы

  1. В чем различия между GLSL mod и HLSL fmod?
  2. Как я могу перевести загадочное описание MSDN fmod в реализацию псевдокода?

GLSL Shader 

uniform float time;
uniform vec2 resolution;
uniform vec2 aspect;

void main( void ) {
  vec2 position = -aspect.xy + 2.0 * gl_FragCoord.xy / resolution.xy * aspect.xy;
  float angle = 0.0 ;
  float radius = length(position) ;
  if (position.x != 0.0 && position.y != 0.0){
    angle = degrees(atan(position.y,position.x)) ;
  }
  float amod = mod(angle+30.0*time-120.0*log(radius), 30.0) ;
  if (amod<15.0){
    gl_FragColor = vec4( 0.0, 0.0, 0.0, 1.0 );
  } else{
    gl_FragColor = vec4( 1.0, 1.0, 1.0, 1.0 );                    
  }
}

HLSL Shader 

struct Psl_VertexShaderInput
{
    float3 pos : POSITION;
};

struct Psl_VertexShaderOutput
{
    float4 pos : POSITION;

};

struct Psl_PixelShaderOutput
{
    float4 Output0 : COLOR0;
};

float3 psl_positionOffset;
float2 psl_dimension;

Psl_VertexShaderOutput Psl_VertexShaderFunction(Psl_VertexShaderInput psl_input)
{
    Psl_VertexShaderOutput psl_output = (Psl_VertexShaderOutput)0;

    psl_output.pos = float4(psl_input.pos + psl_positionOffset, 1);


    return psl_output;
}

float time : TIME;
float2 resolution : DIMENSION;


Psl_PixelShaderOutput Psl_PixelShaderFunction(float2 pos : VPOS)
{
    Psl_PixelShaderOutput psl_output = (Psl_PixelShaderOutput)0;

    float2 aspect = float2(resolution.x / resolution.y, 1.0);
    float2 position = -aspect.xy + 2.0 * pos.xy / resolution.xy * aspect.xy;
    float angle = 0.0;
    float radius = length(position);
    if (position.x != 0.0 && position.y != 0.0)
    {
        angle = degrees(atan2(position.y, position.x));
    }
    float amod = fmod((angle + 30.0 * time - 120.0 * log(radius)), 30.0);
    if (amod < 15.0)
    {
        psl_output.Output0 = float4(0.0, 0.0, 0.0, 1.0);
        return psl_output;
    }

    else
    {
        psl_output.Output0 = float4(1.0, 1.0, 1.0, 1.0);
        return psl_output;
    }

}

technique Default
{
    pass P0
    {
        VertexShader = compile vs_3_0 Psl_VertexShaderFunction();
        PixelShader = compile ps_3_0 Psl_PixelShaderFunction();
    }
}

1 Ответ

16 голосов
/ 30 сентября 2011

Как вы уже заметили, они разные. GLSL mod всегда будет иметь тот же знак, что и y, а не x. Иначе это то же самое - значение f такое, что x = i*y + f, где i - целое число, а |f| < |y|. Если вы пытаетесь создать какой-то повторяющийся узор, GLSL mod - это то, что вам нужно.

Для сравнения, HLSL fmod эквивалентен x - y * trunc(x/y). Они одинаковы, когда x/y положительный, отличаются, когда x/y отрицательный.

...